; Do a hexdump of the data in that is in a 512 byte (typically a BIOS DMA) buffer
; [HL] points to the buffer. Change values for [DE] below for different size buffers 
; No registers modified    (INTEL)
 
HEXDUMP:
      PUSH  PSW        ;Save everything
      PUSH	 B
      PUSH  D			 
      PUSH  H
      CALL	ZCRLF       ;CR/LF first
 
	MVI	D,32		;print 32 lines
	MVI	E,16		;16 characters across
      PUSH  D
      PUSH  H           ;Save the buffer location
;
SF172:CALL	ZCRLF
SF175:CALL	BLANK
	MOV	A,M
	CALL	LBYTE		;Display A on CRT/LCD
	INX	H
	DCR	E
	JNZ	SF175
	MVI	E,16
	DCR	D
	JNZ	SF172
;
	CALL	ZCRLF
      POP   H		 ;Get buffer address again
      POP   D           ;Get chars/line again
;
XF172:CALL	ZCRLF		;Now show as ascii
XF175:CALL	BLANK       ;send a space character
	MOV	A,M
	ANI	7FH
	CPI	' ' 		;FILTER OUT CONTROL CHARACTERS
	JNC   XT33
XT22:	 MVI	A,'.'
XT33:	 CPI	07CH
	JNC	XT22
	MOV	C,A		;SET UP TO SEND
	CALL	ZCO
	INX	H
	DCR	E
	JNZ	XF175
	MVI	E,16
	DCR	D
	JNZ	XF172
	CALL	ZCRLF
       POP   H
       POP   D
       POP   B
      POP   PSW
	RET
;
BLANK:MVI	C,' '
	CALL	ZCO
	RET
;
ZCRLF:MVI	C,CR
	CALL	ZCO
      MVI	C,LF
	CALL	ZCO
	RET